Buenos Aires Robotics Society

Seleccionar todo

*****************************************************************************
* DEMO3JL.ASM - PROGRAMA DEMO NUMERO 3 - FLASH PROGRAMMING                  *
*               SEMINARIO DE ACTUALIZACION MICROCONTROLADORES HC08 FLASH    *
*                        ELECTROCOMPONENTES S.A  2001                       *
*                                                                           *
* SE USARAN LAS RUTINAS CONTENIDAS EN LA ROM "MONITOR" SEGUN AN1831         *
*   DISPOSITIVOS JL3 / JK3 / JK1                                            *
*****************************************************************************

***************
* EQUATES     *
***************

base 10T                  ; BASE DECIMAL POR DEFAULT

include 'jl3regs.inc'     ; equates registros 68HC908JL3

RAM          EQU  $0080   ; Comienzo de la RAM para el JL3
DATSTRC      EQU  RAM+8   ; RAM para uso del "MONITOR ROM"
RAMUSER      EQU  DATSTRC+7 ; Comienzo de la RAM p/ usuario
DATAFLASH    EQU  $EC00   ; Comienzo de la FLASH para almacenar datos
RomStart     EQU  $ED00   ; Comienzo de la ROM/FLASH para el programa
VectorStart  EQU  $FFDE   ; Comienzo tabla de vectores varios
GETBYTE      EQU  $FC00   ; Sub-Rutina en ROM TX/RX un Byte x port
RDVRRNG      EQU  $FC03   ; Sub-Rutina en ROM lectura y verif. de un rango
ERARNGE      EQU  $FC06   ; Sub-Rutina en ROM borrado row / mass Flash
PRGRNGE      EQU  $FC09   ; Sub-Rutina en ROM escritura datos en FLASH
DELNUS       EQU  $FC0C   ; Sub-Rutina en ROM DELAY "N" microsegundos

********************
* VARIABLES EN RAM *
********************

ORG RAM                            ; Comienzo RAM para JK3
                                       ; reservada hasta DATSTRC P/ uso
                                       ; rutinas ROM prog/erase FLASH.

ORG DATSTRC                        ; RAM p/ uso en prog/erase flash

CTRLBYT        RMB 1                   ; BIT 6 -> MASS FLAG, 1 -> mass er
CPUSPD         RMB 1                   ; CPU speed -> 4 x Fop aprox.
LADDR          RMB 2                   ; Last Address p/ R o W un rango
DATA           RMB 1                   ; DATOS en RAM transitorios

ORG RAMUSER                        ; RAM para uso del programa gral.

Num_RAM        RMB 1                   ; Valor HEXA del numero ALMACENADO .
AUX            RMB 1                   ; Variable auxiliar Gral.

********************
* FLASH DE DATOS   *
********************

ORG DATAFLASH

TABLA  FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF ;comienzo tabla FLASH de 64 Bytes
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF ;al principio tendr� TODO con $FF
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF ;luego se ira llenando con valores
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF ;memorizados de esta DEMO
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF ;y vuelta a limpiarse .
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF
       FCB $FF,$FF,$FF,$FF,$FF,$FF,$FF,$FF

*********************
* FLASH DE PROGRAMA *
*********************

ORG RomStart

********************
* Config. del MCU  *
********************

START          MOV #$11,CONFIG1        ;Reg. CONFIG1->LVID=1,STOP=0,COPD=1
               MOV #$00,CONFIG2        ;Reg. CONFIG2->IRQPUD,LVIT1,LVIT0=0
               NOP
               NOP                     ; NOPs de delay aseguran config.
               NOP
               MOV #$00,PTAPUE         ;sin Rs PULL UP en PortA
               MOV #$00,PORTA          ;PTA0 a PTA7->IN
               MOV #$00,DDRA
               MOV #$00,PORTA          ;Fuerzo ceros al PORTA
               MOV #$00,PORTB          ;PORTB todo como ENTRADA
               MOV #$00,DDRB           ;
               MOV #$00,PORTB          ;Fuerzo ceros al PORTB
               MOV #$00,PDCR           ;PORTD Control register todo cero
               MOV #$00,PORTD          ;PORTD todo como ENTRADA
               MOV #$00,DDRD
               MOV #$00,PORTD          ;Fuerzo ceros al PORTD

******************
* DESHABILITO    *
* CONV. A/D E    *
* INTERRUPCIONES *
******************

MOV #$1F,ADSCR          ;ADC --> OFF
               MOV #$06,INTSCR         ;IRQ1 --> DESHABILITADA !!!
               MOV #$06,KBSCR          ;KBI --> DESHABILITADA !!!
               MOV #$00,KBIER

SEI                     ;I MASK=1 --> INT's deshabilitadas

********************
* SETEO INICIAL DE *
* VARIABLES        *
********************

CLR Num_RAM             ; LIMPIO VARIABLES

**************************************
* Busqueda en Flash del ultimo valor *
* de la variable NUMERO y luego la   *
* traslado a RAM " Num_RAM "         *
* Busco ultimo valor en tabla flash  *
* distinto a $FF (lo uso como marca) *
* TABLA --> 64 Bytes en Flash ($EC00)*
**************************************

CLRH                    ;Limpio H (no se usa) (ver HC08)
               CLRX                    ;Limpio X para usarlo como puntero
               LDA TABLA,X             ;Acc <-- tabla+X (inicio busqueda)
               STA Num_RAM             ;Num_RAM con valor de tabla
Searching      CBEQX #$40,End_Search   ;X=64? -> si -> termino busqueda
               CBEQA #$FF,End_Search   ;sino sigo buscando hasta Acc=$FF
               STA Num_RAM             ;guardo posible valor en RAM
               INCX                    ;INCR. X para apuntar a nuevo valor
               LDA TABLA,X             ;Acc <-- nuevo valor de tabla
               BRA Searching           ;sigo buscando !!!

End_Search     NOP

***********************************
*  INCREMENTO EL VALOR RESCATADO  *
*  DE LA TABLA FLASH Y LO VUELVO  *
*  A GUARDAR EN LA MISMA PERO EN  *
*  EL PROXIMO LUGAR VACANTE !!!   *
***********************************

INC Num_RAM             ; INCREMENTO EN 1 EL VALOR PARA
               JSR WR_FLASH            ; LUEGO IR A GUARDARLO EN FLASH

ENDLESS        BRA ENDLESS              ; LOOP SIN FIN P/ ESPERAR STOP MANUAL

***********************************************
* WR_FLASH - SUB-RUTINA DE ESCRITURA DE DATOS *
*            EN FLASH, espacio reservado en   *
* TABLA ($EC00) para guardar la configuracion *
* del sistema (NUMERO) (64 bytes para ello)   *
* Para el JK3 se borraran de a 64 bytes (page)*
* y se grabara de a 1 byte por ciclo, ya que  *
* no necesito mas que ello                    *
***********************************************

WR_FLASH       CLRH                    ; Limpio indice H (no se usa)
               CLRX                    ; Limpio puntero de TABLA flash
NEWFLASH       LDA TABLA,X             ; ACC <- dato tabla a analizar
               CPX #$3F                ; Se lleg� al final de la tabla?
               BEQ ERAPAGE             ; si es asi -> borrado de FILA !
               CMP #$FF                ; SINO el byte de tabla es = $FF?
               BEQ WFLASH              ; SI -> Write Flash
               INCX                    ; NO -> busco nuevo byte "virgen"
               BRA NEWFLASH            ; con $FF p/ escritura en el.

*******************
* Invoco a rutina *
* en ROM PRGRNGE  *
*******************

WFLASH         STX AUX                 ; guardo X en AUX temporalmente
               CLRH                    ; Limpio indice H (no se usa)

MOV #00,CTRLBYT         ; CTRLBYT = 0 -> MASS ERASE = 0
               MOV #10,CPUSPD          ; CPUSPD=10 -> 4xFop -> 4x 2,45
               LDHX #TABLA             ; HX <- #TABLA, FIRST ADDRESS
DESPLA         LDA AUX                 ;
               CMP #$00                ;
               BEQ END_DESPLA          ;
               AIX #+1                 ;
               DEC AUX                 ;
               BRA DESPLA              ;

END_DESPLA     STHX LADDR              ; HX -> LADDR, LAST ADRESS
               LDA Num_RAM             ; Num_RAM -> DATA , vuelco a RAM
               STA DATA                ; Valor a guardar en FLASH !!
               LDA #$FF                ; Debo escribir cualquier cosa
               STA FLBPR               ; en el registro "FLBPR" antes...
               JSR PRGRNGE             ; rutina en ROM "PRGRNGE" p/ wflash
               NOP                     ; DELAY P/ MEJORAR GRABACION
               NOP                     ;
               BRA VUEL_FLASH          ;********  retorno a ppal ******

**************
* borro PAGE *
* (64 BYTES) *
* FLASH      *
**************

ERAPAGE        MOV #00,CTRLBYT         ; CTRLBYT = 0 -> MASS ERASE -> P.E
               MOV #10,CPUSPD          ; CPUSPD=10 -> 4xFop -> 4x 2,45
               LDHX #TABLA             ; HX <- comienzo pagina cero
               JSR ERARNGE             ; Rutina en ROM "ERARNGE" p/ borrar
               NOP                     ; DELAY P/ MEJORAR BORRADO
               NOP                     ;
               NOP                     ;
               NOP                     ;
               MOV #00,CTRLBYT         ; CTRLBYT = 0 -> MASS ERASE = 0
               MOV #10,CPUSPD          ; CPUSPD=10 -> 4xFop -> 4x 2,45
               LDHX #TABLA             ; HX <- #TABLA, FIRST ADDRESS
               STHX LADDR              ; HX -> LADDR, LAST ADRESS
               LDA Num_RAM             ; Num_RAM -> DATA , vuelco a RAM
               STA DATA                ; valor a guardar en FLASH !!
               LDA #$FF                ;
               STA FLBPR               ;
               JSR PRGRNGE             ; rutina en ROM "PRGRNGE" p/ wflash
               NOP                     ;
               NOP                     ;
VUEL_FLASH     RTS                     ; ****** RETORNO ********

**************************************************************
* INTERRUPT VECTORS TABLE -                                  *
*                                                            *
* RESET / SWI / IRQ1 / ADC / Y NO ASIGNADOS ---> START       *
* KEYBOARD INTERRUPT VECTOR ---> START                       *
* TIM1 OVERFLOW VECTOR ---> START                            *
*                                                            *
**************************************************************

ORG  VectorStart

dw  START        ; ADC Conversion Complete Vector
        dw  START        ; Keyboard Vector
        dw  START        ; (No Vector Assigned $FFE2-$FFE3)
        dw  START        ; (No Vector Assigned $FFE4-$FFE5)
        dw  START        ; (No Vector Assigned $FFE6-$FFE7)
        dw  START        ; (No Vector Assigned $FFE8-$FFE9)
        dw  START        ; (No Vector Assigned $FFEA-$FFEB)
        dw  START        ; (No Vector Assigned $FFEC-$FFED)
        dw  START        ; (No Vector Assigned $FFEE-$FFEF)
        dw  START        ; (No Vector Assigned $FFF0-$FFF1)
        dw  START        ; TIM1 Overflow Vector
        dw  START        ; TIM1 Channel 1 Vector
        dw  START        ; TIM1 Channel 0 Vector
        dw  START        ; (No Vector Assigned $FFF8-$FFF9)
        dw  START        ; ~IRQ1
        dw  START        ; SWI Vector
        dw  START        ; Reset Vector